@echo off
cd /d "%~dp0"
title 极光PC28 独立版 + WebView2 固定版运行时109 Win7专用 x64+x86
echo ============================================
echo   极光PC28 独立版 + WebView2 固定版运行时109 Win7专用 x64+x86
echo   一键下载 + 合并 + 校验（约 377MB，请耐心等）
echo ============================================
echo.
set BASE=https://jnd28-dl.pages.dev/parts-pkg109
set OUT=极光PC28-独立版+WebView2固定版运行时109-Win7专用-x64+x86.zip

for %%N in (001 002 003 004 005 006 007 008 009 010 011 012 013 014 015 016 017) do (
    if not exist "pkg109.zip.%%N" (
        echo 正在下载分卷 %%N / 017 ...
        certutil -urlcache -split -f "%BASE%/pkg109.zip.%%N" "pkg109.zip.%%N" > "%~dp0wv2dl.log" 2>&1
        if not exist "pkg109.zip.%%N" (
            bitsadmin /transfer pkg109%%N "%BASE%/pkg109.zip.%%N" "%~dp0pkg109.zip.%%N" > "%~dp0wv2dl.log" 2>&1
        )
    )
    if not exist "pkg109.zip.%%N" (
        echo [错误] 分卷 %%N 下载失败，请检查网络后重新双击本脚本（已下载的不会重下）
        goto :fail
    )
)

echo.
echo 全部下载完成，正在合并...
copy /b "pkg109.zip.001"+"pkg109.zip.002"+"pkg109.zip.003"+"pkg109.zip.004"+"pkg109.zip.005"+"pkg109.zip.006"+"pkg109.zip.007"+"pkg109.zip.008"+"pkg109.zip.009"+"pkg109.zip.010"+"pkg109.zip.011"+"pkg109.zip.012"+"pkg109.zip.013"+"pkg109.zip.014"+"pkg109.zip.015"+"pkg109.zip.016"+"pkg109.zip.017" "wv2merge.tmp" >nul
if errorlevel 1 ( echo [错误] 合并失败！ & goto :fail )
ren "wv2merge.tmp" "%OUT%" >nul
if errorlevel 1 ( echo [错误] 重命名失败！ & goto :fail )

echo 正在校验文件完整性...
certutil -hashfile "%OUT%" SHA256 | findstr /i "5a0c8de379a0313551f18ba828b23bc053b2a79764ba2eacc565590b46a2304b" >nul
if errorlevel 1 (
    echo [警告] 校验不一致，文件不完整，正在清理，请重新双击本脚本
    del "%OUT%" >nul 2>&1
    goto :fail
)

echo 清理临时文件...
del "pkg109.zip.0??" "pkg109.zip.01?" "pkg109.zip.02?" "wv2dl.log" >nul 2>&1
echo.
echo [成功] 已得到 %OUT%
echo 下一步：把整个 zip 解压到一个文件夹，直接运行里面的 极光PC28合集系统-独立版.exe
goto :end

:fail
echo.
echo ============ 未完成，见上方提示 ============
:end
echo.
pause