@echo off
chcp 65001 >nul
cd /d "%~dp0"
echo ============================================
echo   WebView2 固定版运行时 109 (Win7 专用) x64
echo   分卷合并脚本
echo ============================================
echo.
echo 请确认 9 个分卷文件 (wv2-109-win7-x64.zip.001 ~ .009)
echo 和本脚本放在同一个文件夹里。
echo.
if not exist "wv2-109-win7-x64.zip.009" (
    echo [错误] 分卷文件不全，请把 9 个分卷都下载到本文件夹！
    pause
    exit /b 1
)
echo 正在合并...
copy /b "wv2-109-win7-x64.zip.001"+"wv2-109-win7-x64.zip.002"+"wv2-109-win7-x64.zip.003"+"wv2-109-win7-x64.zip.004"+"wv2-109-win7-x64.zip.005"+"wv2-109-win7-x64.zip.006"+"wv2-109-win7-x64.zip.007"+"wv2-109-win7-x64.zip.008"+"wv2-109-win7-x64.zip.009" "WebView2固定版运行时109-Win7专用-x64.zip" >nul
if errorlevel 1 (
    echo [错误] 合并失败！
    pause
    exit /b 1
)
echo.
echo 正在校验文件完整性...
certutil -hashfile "WebView2固定版运行时109-Win7专用-x64.zip" SHA256 | findstr /i "aecaba1b59b2590d37ae7bba1a6713c065849ce76e190dcd6b4310a27a1fde70" >nul
if errorlevel 1 (
    echo [警告] 校验值不一致，文件可能下载不完整，请重新下载分卷！
) else (
    echo [成功] 校验通过！
    echo.
    echo 接下来：解压 zip，把里面的 WebView2Runtime 文件夹
    echo 放到「极光PC28合集系统-独立版.exe」同一目录即可。
)
echo.
pause